*-----------------------------------------------------------------------
* Filename:		SV83.inc  25/10/97  V1
* Simulator:		PSpice
* Device type:		Power pentode
* Device model:		Svetlana SV83
*
* Author:		Duncan Munro
* Date:			25/10/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
*
* The following parameters are not modelled:
*
*   (1) Heater
*   (2) Grid current is an approximation
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        S  Screen
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT SV83 A S G K
*
* Calculate contribution to cathode current
*
Eat	at	0	VALUE={0.636*ATAN(V(A,K)/15)}
Egs	gs	0	VALUE={LIMIT{V(S,K)/19+V(G,K)*1.2+V(A,K)/1400,0,1E6}}
Egs2	gs2	0	VALUE={PWRS(V(gs),1.5)*1.6}
Ecath  	cc    	0 	VALUE={V(gs2)*V(at)}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={LIMIT{3.5E-3*V(cc),0,9999}}
*
* Calculate screen current
*
Escrn	sc	0	VALUE={V(gs2)*(1.1-V(at))}
Gs     	S     	K	VALUE={2.0E-3*V(sc)*LIMIT{V(S,K),0,10}/10}
*
* Grid current (approximation - does not model low va/vs)
*
Gg	G	K	VALUE={PWR(LIMIT{V(G,K)+1,0,1E6},1.5)*50E-6}
*
* Capacitances
*
Cg1	G	K	13.5p
Cak	A	K	7.0p
Cg1a	G	A	0.07p

.ENDS