*-----------------------------------------------------------------------
* Filename:		SV811-3s.inc  V2  16/6/97
* Simulator:		SPICE 3f4
* Device type:		Power triode
* Device model:		Svetlana SV811-3
*
* Author:		Duncan Munro
* Date:			15/6/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
* The following parameters are not modelled:
*
*   (1) Filament: A "cathode" connection is made which
*       should be connected to a potential which is the
*	average of the two filament terminals.
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT SV811-3 A G K
*
* Calculate contribution to cathode current
*
Bme	me	0	V=(URAMP(V(A,K))^1.5)/4500
Bmu	mu	0	V=V(G,K)
Bgs	gs	0	V=URAMP(V(A,K)+V(mu)*3.4)
Bgs2	gs2	0	V=(V(gs)^1.5)*25E-6
Bcath	cc	0	V=V(gs2)-(U(V(gs2)-V(me))*(V(gs2)-V(me)))
*
* Calculate anode current
*
Bat	at	0	V=0.636*ATAN(V(A,K)/30)
Ba     	A     	K     	I=V(cc)
*
* Calculate grid current
*
Bg	G	K	I=(URAMP(V(G,K)+1)^1.5)*(2-V(at))*30E-6
*
* Capacitances
*
Cgk	G	K	7p
Cga	A	G	8p

.ENDS