*-----------------------------------------------------------------------
* Filename:		SV3CX300.inc  V1  17/6/97
* Simulator:		PSpice
* Device type:		Power triode
* Device model:		Svetlana 3CX300A1
*
* Author:		Duncan Munro
* Date:			17/6/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
* The following parameters are not modelled:
*
*   (1) Heater is not modelled.
*
*   (2) Grid current is not modelled, as this valve is
*       designed for A1 and AB1 operation.
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT SV3CX300 A G K
*
* Calculate reduction in mu at large negative
* grid voltages
*
Emu	mu	0	VALUE={PWRS(V(G,K),0.98)}
*
* Calculate change in shape with reducing grid voltage
*
Eshape	shape	0	VALUE={(280+V(G,K))/280}
*
Egs	gs	0	VALUE={LIMIT{V(A,K)+V(G,K)*7.5,0,1E6}}
Egs2	gs2	0	VALUE={PWRS(V(gs)*V(shape),1.5)*135E-6}
Ecath  	cc    	0 	VALUE={V(gs2)}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={V(cc)}
*
* Capacitances
*
Cgk	G	K	25p
Cga	A	G	10p
Cak	A	K	1p

.ENDS