*-----------------------------------------------------------------------
* Filename:		6BM8T.inc  V1  10/7/97
* Simulator:		PSpice
* Device type:		Signal triode
* Device model:		6BM8/ECL82 (triode section)
*
* Author:		Duncan Munro
* Date:			10/7/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
* The following parameters are not modelled:
*
*   (1) Heater model
*
*   (2) Grid current
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------

.SUBCKT 6BM8T A G K
*
* Calculate contribution to cathode current
*
Eat	at	0	VALUE={0.636*ATAN(V(A,K)/10)}
Erp	rp	0	VALUE={PWR(LIMIT{V(A,K),0,10000},0.7)}
Egs	gs	0	VALUE={LIMIT{V(rp)*2.1+PWRS(V(G,K),0.8)*22,0,1E6}}
Egs2	gs2	0	VALUE={PWRS(V(gs),1.5)*12.45E-6}
Ecath  	cc    	0 	VALUE={V(gs2)*V(at)}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={V(cc)}
*
* Capacitances
*
Cgk	G	K	2.7p
Cga	A	G	4p
Cak	A	K	4p

.ENDS